 |
Набор следующей программы.
|
|
|
|
Основы программирования
На Паскаль АВС
Составитель: Овчинников А. А.
г. Волгоград
2012 год
Рецензент:
к.т.н., ст. преподаватель кафедры «Программное обеспечение автоматизированных систем» (ПОАС) ВолгГТУ С.А. Овчинников
Аннотация
Пособие предназначено для обучения основам программирования школьников на начальном этапе. Необходимость такого пособия вызвана тем, что в базовых учебниках для средней школы раздел программирования либо вообще не представлен, либо представлен недостаточно.
В то время, как ученики нуждаются в пособии, по которому можно подготовить домашнее задание, изучить пропущенный материал или поработать дополнительно. Тем более, что пакет Паскаль АВС имеет в своей базовой комплектации «Электронный задачник», что значительно расширяет возможности пособия, так как после каждой темы даются упражнения по этому задачнику.
Надеюсь, что данное пособие может оказаться полезным и учителям информатики.
В 1970 г. профессор Никлаус Вирт из Швейцарии обосновал и разработал язык высокого уровня – Паскаль. Этот язык отличается простотой и стройностью, качествами, которые обеспечивают Паскалю популярность уже на протяжении нескольких десятилетий.
В настоящее время удобной в учебном процессе является система программирования Pascal ABC (Паскаль АВС). Система предназначена для обучения программированию на языке Паскаль и ориентирована на школьников и студентов младших курсов. Кроме того, в пакете имеется Электронный задачник.
Эта система призвана осуществить переход от простейших программ к модульному, объектно-ориентированному, событийному и компонентному программированию.
|
|
|
Введение. Установка Паскаль АВС
Все авторские права программного комплекса Pascal ABC 3.0 & Programming Taskbook 4.5 Mini Edition (называемого в дальнейшем системой PABC-PT ME) принадлежат только авторам: С.С.Михалковичу и М.Э.Абрамяну.
Система PABC-PT ME является бесплатной и распространяется свободно при условии, что настоящий дистрибутив не изменен. Ни одно частное лицо или организация не может брать плату за распространение системы PABC-PT ME.
Скачать программный комплекс можно в интернете совершенно бесплатно и установить на свой компьютер.
В скачанном пакете для установки запустите файл PABCInstall и в появившемся окне нажмите кнопку "Установка".
После установки автоматически запускается программа регистрации и настройки PABCSetup. В дальнейшем эту программу можно запустить повторно с помощью команды "PABC Setup - Регистрация и настройка" пункта "Pascal ABC" в группе "Программы" главного меню Windows.
ТЕМА 1. Знакомство с системой программирования
Паскаль АВС
ВНИМАНИЕ! Для каждого пользователя рекомендуется создать отдельную папку, например, KURS, а в ней папки для файлов.
Для запуска Паскаль АВС необходимо запустить ярлык Pascal ABC. На экране появится среда программирования Паскаль АВС (оболочка). Среда программирования – это пакет взаимосвязанных файлов, которые позволяют набирать, редактировать, запускать и отлаживать программы.
После запуска ярлыка на рабочем столе открывается окно:
 |
Первая строка экрана – меню интегрированной среды, следующая строка – панель инструментов, нижняя строка экрана – строка подсказки и состояния интегрированной среды. Между ними расположено окно редактирования – рабочее поле, в котором можно открывать несколько вкладок для разных программ.
Окно редактирования предназначено для ввода и редактирования текста программы. Место ввода информации обозначено курсором. В верхней левой части окна редактирования выводится служебное имя редактируемого файла, например: Program1.pas
|
|
|
1. Найдите строку Меню (сверху) и строку-подсказку (снизу).
2. Поочередно войдите в указанные ниже разделы Меню (активизируйте Меню мышью).
3. Найдите следующие команды:
В меню Файл
Новый – создать новый фал
Oткрыть – открыть файл
Сохранить – сохранить файл
Сохранить как… – сохранить под новым именем
Выход – выйти из Паскаля
В меню Правка
Отменить – отменить изменение
Восстановить – вернуть изменение
В меню Программа
Выполнить – выполнить программу
Остановить – остановить программу.
Первые шаги
Наберем простейшую программу, соответствующую условию задачи:
Ввести в компьютер два целых числа, найти их сумму, результат вывести на экран с поясняющим текстом.
Внимание! Две косые черты (//) отделяют комментарии, их набирать не нужно.
program raschet; // название программы
uses crt; // подключаемые модули
var x, y, s:integer; // объявление имен переменных и их типа
begin // начало исполнительной части
writeln(’Введите два целых числа’); // написать на экране текст
readln(x,y); // прочитать данные с клавиатуры и
// запомнить их в переменных
s:=x+y; // выполнить расчет и запомнить его в
// переменной
writeln(‘Сумма чисел =’,s); // написать на экране текст и значение
// переменной
end. // конец программы
4. Просмотрите текст файла, обратите внимание на стуктуру программы.
Структура простейших программ выглядит следующим образом:
program...; заголовок программы и ее имя
var...; блок объявления переменных и их типа
begin начало исполнительной части программы
...; предложения, обеспечивающие
...; выполнение
...; программы
end. конец программы (точка обязательна)
Программа на Паскале составляется из отдельных законченных элементов, называемых предложениями. В Паскале текст программы обычно начинается особым предложением – заголовком следующего вида:
program proba;
где proba – имя текущей программы.
Заголовок необязателен.
В качестве имени программы можно применять комбинацию английских букв и цифр, следует писать в одно слово и нельзя применять служебные слова языка.
Каждое предложение языка должно отделяться от следующего за ним точкой с запятой (;).
|
|
|
Исключение составляют комментарии. Они не отделяются точкой с запятой.
Обычно каждое предложение записывается с новой строки для наглядности и более легкого понимания текста. Для этих же целей используют отступы и выравнивания.
Комментарии предназначены для пояснения задачи и для временного исключения из текста программы некоторых операторов. В тексте они выделяются фигурными скобками { } или отделяются двумя косыми чертами //. Комментарии игнорируются компьютером при выполнении, однако при выводе текста программы – печатаются.
В Паскале имеется особая группа слов, таких как, например: begin, for, end, program и другие, за которыми закреплены специальные смысловые значения. Такие слова называются служебными (зарезервированными) и должны употребляться в строгом соответствии с заложенным в них смыслом.
Существует и другая группа имен, имеющих стандартно определенный смысл, например, integer, writeln и другие. Их так и называют – стандартные или предопределенные имена.
Под именем программы располагается ее декларативная часть, здесь компьютеру сообщается обо всех именах констант и переменных, определяемых программистом, и о той роли, которую эти имена должны исполнять в программе.
За декларативной частью следует исполнительная часть программы, обрамляемая словами-ограничителями (логическими скобками): begin и end. Между указанной парой слов и размещаются предложения, выполняющие в программе те или иные действия. Исполнительную часть программы называют телом программы.
5. Запустите набранную программу на выполнение. Если после запуска программы внизу окна появляется красная строчка с сообщением (рисунок см. ниже), то в строке, где находится курсор или в предыдущей (но не всегда, это зависит от ошибки!), внимательно просмотрите всю строчку, найдите и исправьте ошибку. Если сами не справитесь, позовите учителя.
Пример ошибки, обнаруженной Паскаль АВС:
6. После исправления всех ошибок и появления в новом окне начала работы программы, введите нужные данные (если в программе подразумевается ввод нескольких переменных, то это следует делать через Enter или пробел!), получите результат работы и проверьте его на правильность. Так как текст программы и ее работа показываются в разных окнах (если подключен модуль Crt), можно сопоставить программные строки и ее выполнение.
|
|
|
Пример работы программы
7. Сохраните набранную программу в своей папке.
8. Разберитесь с работой программы и измените ее так, чтобы она вычисляла не сумму, а разность чисел. Проверьте правильность работы измененной программы. Сохраните программу под новым именем в своей папке.
Набор следующей программы.
9. Активизируйте пункт Файл и создайте новый файл (Новый).
10. Наберите текст программы (см. ниже). При наборе текста программы соблюдайте позиционирование (отступы) строк. Это не влияет на работу программы, но делает ее читабельной и облегчает поиск ошибок.
11. В следующей программе подсчитывается доход клиента за 1 год в зависимости от банковского процента и от величины денежного вклада.
Внимание! Текст в фигурных скобках является пояснением: его не нужно набирать. Обратите внимание на значение служебных слов языка.
program doxod; {название программы}
uses crt; {подключаемые модули (библиотеки)}
var b,a:integer; {объявление переменных и их типа}
c:real;
begin {начало программы}
clrscr; {очистка экрана}
writeln('Доход от вклада'); {вывод текста на экран
с переводом курсора на следующую строку}
write('Введите величину вклада в рублях: '); {вывод текста на экран без перевода
курсора на следующую строку}
readln(b); {ввод целого числа в
переменную b с переходом на
следующую строку}
write('Введите величину банковского процента ');
readln(a);
c:=a*b/100; {расчет значения переменной с }
writeln('Ваш доход =',c,' рублей'); {вывод текста, значения переменной и текста}
end.
12. Запустите программу на выполнение. Введите следующие данные:
Введите величину вклада в рублях: 1000
Введите величину банковского процента. 10
В результате должен получиться ответ:
Ваш доход =100 рублей
13. Снова запустите программу и введите другие разумные исходные данные.
Привыкайте понимать сообщения об ошибках!
14. Вернитесь в текст, сотрите знак "; " в любом месте программы и запустите ее на выполнение. Проанализируйте сообщение об ошибке (красная строчка с сообщением).
15. Исправьте ошибку, затем сотрите точку после последнего End в программе. Эта ошибка часто встречается у начинающих. Запустите программу и посмотрите, как реагирует Паскаль на подобную ошибку.
16. Сотрите любую букву, например, в слове writeln. Посмотрите, как реагирует Паскаль на подобную ошибку.
17. Сотрите в блоке var объявленную переменную и посмотрите, как отреагирует компьютер на запуск программы с такой ошибкой. Запоминайте сообщения компьютера.
|
|
|
18. Исправьте ваши ошибки и сохраните программу.
19. Напишем программу, соответствующую следующей задаче:
Запросить имя пользователя и его возраст. Определить год рождения (текущий год запросить с клавиатуры), вывести его на экран и попрощаться по имени.
program vozrast;
uses crt;
var voz, gr, tg:integer; {для возраста, года рождения, текущего года: целые числа}
im:string; {для имени: буквы, слова}
begin
clrscr;
write('Как тебя зовут? ');
readln(im);
write('Сколько тебе лет? ');
readln(voz);
write('Какой сейчас год? ');
readln(tg);
gr:=tg-voz;
writeln('Ты родился в ',gr,' году');
writeln('До свидания, ',im);
end.
Запомните:
тип integer для хранения целых чисел
тип real для хранения любых чисел, в том числе дробных
тип string для хранения слов и букв
clrscr очистить экран
write написать на экране и оставить курсор в текущей строке
writeln написать на экране и перейти на следующую строку
readln прочитать данные с клавиатуры и поместить их в переменную
Упражнения
Выполните задания с Begin1 ° по Begin8 °, с Begin31 ° по Begin34 ° по электронному задачнику (стр.11). Открыть его можно в режиме Помощь – Электронный задачник РТ. Задачник откроется отдельным файлом в формате pdf.
ТЕМА 2. Типы переменных. Простые числовые операции и функции
Операторы ввода-вывода данных.
В Паскале используется несколько типов представления числовых значений, на начальном этапе будут рассмотрены лишь некоторые из них:
integer – целые числа в интервале от -2147483648 до 2147483647
real – вещественные (реальные) – целые и дробные положительные и отрицательные числа
Описания констант в декларативной части производится перед переменными, и предусматривают определенную форму записи чисел (дополнительно тип константы не оговаривается): если константа записана с точкой, тип константы считается real. При записи значения константы используется знак равенства.
Пример описания констант:
const
c1=3.14159265; // с1 имеет тип real
с2=2; // c2 имеет тип integer
Переменная – это вид объектов в программе, предназначенный для хранения информации во время выполнения программы. По правилам Паскаля каждая переменная должна быть объявлена, т.е. описана в декларативной части программы.
Переменная не имеет какого-либо конкретного значения до тех пор, пока компьютеру не будет дано точное предписание, поместить что-либо определенное в соответствующую ячейку памяти.
На Паскале такого рода предписание обычно выражается предложением назначения, имеющим вид:
имя_переменной: =выражение_или_значение
например: a:=25; или rt:=a+b;
Выполнение такого предложения начинается вычислением выражения, стоящего справа от символа назначения (:=). Полученное значение потом помещается в переменную (присваивается ей), указанную слева от =:
Описание переменных следует за описанием констант. В описании переменных после двоеточия указывается тип переменной:
var a,d,c: integer;
b,f: real;
В Паскале возможны следующие действия (группы операций записаны в порядке приоритета):
1) Операция возведения в степень (в стандартном Паскале отсутствует) – функция i:=power(x,y), где i - результат, x - основание, y - степень;
2) умножение (*), деление (/), деление целочисленное (div), получение остатка от целочисленного деления (mod);
3) сложение (+), вычитание (-).
В пределах одной группы приоритета порядок выполнения операций, если нет скобок, определяется последовательностью записи.
Если хотя бы одна из переменных, используемых в операциях умножения, сложения, вычитания относится к типу real, результат операции будет типа real.
Результат операции деления всегда типа real. Результат операций div и mod - integer.
Пример записи математической операции:
y=(а:b+c2-d)*c
в программе на Паскале это будет выглядеть так:
y:=(a/b+sqr(c)-d)*c;
Примечание. Квадрат числа sqr(c) можно (и проще!) записать как с*с
Oбратите внимание на использование знака операции присваивания:=
При проведении математических операций следует учитывать, что вещественные числа (real) представляются с некоторым приближением.
Некоторые стандартные математические функции
При использовании стандартных функций необходимо контролировать тип аргумента (возможные типы указаны в скобках).
a:=random(x) – случайное число (если аргумент не указан, то результат real – число в интервале от 0 до 1, если x целое число от 0 до 65535, то результат случайное целое число в интервале от 0 до х-1;
a:=abs(x) – модуль (абсолютная величина) x (real или integer);
a:=int(x) – целая часть числа x (число real, результат integer), округление не проводится, дробная часть отсекается;
a:=frac(x) – дробная часть числа x (число и результат real),
a:=round(x) – целое число, полученное в результате округления числа x по правилам математики
a:=sqr(x) – квадрат числа x (real, integer);
a:=sqrt(x) – квадратный корень из числа x (real, x>0);
a:=sin(x) – синус x (x задается в радианах, real);
a:=cos(x) – косинус x (x задается в радианах, real);
a:=arctan(x) – арктангенс x (real);
а:=power(x,y) – степень числа
pi – число пи.
Наберите следующую программу и разберитесь в ее работе:
Вычислить сумму цифр трехзначного числа a, введенного с клавиатуры. В программе каждая цифра определяется как количество сотен, десятков и единиц с помощью арифметических операций.
program summa;
uses crt;
var a, s, d, e, o: integer;
begin
writeln('Сумма цифр трехзначного числа');
write('Введите целое трехзначное число ');
readln(a);
clrscr;
{первый способ}
s:= trunc(a/100); {количество сотен}
d:= trunc((a-s*100)/10); {количество десятков}
e:=a-s*100-d*10; {количество единиц}
writeln('Сумма цифр трехзначного числа=', s+d+e);
{второй способ}
s:=a div 100; {количество сотен}
o:=a mod 100;
d:=o div 10; {количество десятков}
e:=a-s*100-d*10; {количество единиц}
writeln('Сумма цифр трехзначного числа=', s+d+e);
end.
Упражнения.
Выполните задания с Begin9 ° по Begin30 ° по электронному задачнику (стр.11). Открыть его можно в режиме Помощь – Электронный задачник РТ.
Задачи для самостоятельного решения
1. Написать программу вычисления расстояния между двумя точками с координатами x1, y1, x2, y2. Использовать теорему Пифагора. Результат вывести на экран с поясняющим текстом.
2. Составить программу, чтобы компьютер запросил имя пользователя и его год рождения, затем подсчитал количество лет, дней и минут, прожитых, примерно, этим человеком. Результаты вывести на экран.
3. Составить программу, чтобы компьютер по закону Ома для участка цепи, запрашивая с клавиатуры значения напряжения на концах участка и его сопротивления, определял и выводил на экран значение силы тока (I=U/R).
4. Составить программу для того, чтобы компьютер, используя генератор случайных чисел, записал на экране случайное число, значение которого лежит в пределах от 0 до 1.
5. Составить программу для того, чтобы компьютер, используя генератор случайных чисел, записал на экране случайное число, значение которого лежит в пределах от 5 до 6.
6. Составить программу для того, чтобы компьютер, используя генератор случайных чисел, записал на экране случайное число, значение которого лежит в пределах от 5 до 10.
7. Составить программу для того, чтобы компьютер, используя генератор случайных чисел, записал на экране случайное число, значение которого лежит в пределах от 5 до 6 и имеет 2 знака в дробной части.
ТЕМА 3. Условный оператор (ветвление)
Условный оператор If в зависимости от значения некоторого условия выполняет либо оператор, стоящий после Then (условие выполняется), либо оператор, стоящий после Еlse (условие не выполняется).
Структура условного оператора:
If условие Then группа операторов [ Else группа операторов];
Перед Else знак "; " никогда не ставится. В квадратных скобках указана необязательная часть.
В качестве условия может быть использовано любое выражение логического типа.
Условия можно объединять с помощью Or – Или и с помощью And – И. Если условий несколько, то каждое из них необходимо заключить в скобки:
If (a>2) and (b<2) Then
Наберите и отладьте программу trеug1
Программа должна запросить три стороны треугольника и по ним определить тип треугольника. Определение типа производится сравнением сторон. После отладки проверьте ее при работе со сторонами
а) 2, 2, 2; ответ должен быть "равносторонний"
б) 4, 4, 8; ответ должен быть "равнобедренный"
в) 4, 3, 5 ответ должен быть "разносторонний".
program treug1;
uses crt;
var a,b,c:integer;
d:string;
begin
clrscr;
write('Введи три стороны треугольника ');
readln (a,b,c);
if (a=b) or (b=c) or (a=c) then d:='треугольник равнобедренный';
if (a=b) and (b=c) then d:='треугольник равносторонний';
if (a<>c) and (a<>b) and (b<>c) then d:='треугольник разносторонний';
writeln (d);
end.
Счетчики
Для подсчета любых данных, ситуаций, событий, удобно использовать счетчики. Счетчиком можно назвать расчетную строку, в которой слева и справа используется одинаковая переменная.
Например, k:=k+… или m:=m*… или d:=d-… и т.д., где вместо многоточия (…) записывается число или переменная.
Строку типа k:=k+1 можно назвать счетчиком количества. Работает она так: число, лежащее в ячейке k увеличить на 1 и снова записать в ту же ячейку.
Вот фрагмент программы, показывающий работу такого счетчика:
readln(a,b,c);
if a>0 then p:=p+1 else o:=o+1;
if b>0 then p:=p+1 else o:=o+1;
if c>0 then p:=p+1 else o:=o+1;
writeln(‘положительных чисел - ’,p, ‘ отрицательных чисел или 0 - ’,o);
так же часто используется счетчик суммы: s:=s+a
Применение счетчиков такого типа будет рассмотрено позднее, в работе циклов.
Работа с символьными переменными
В Паскаль АВС используется несколько типов символьных переменных, в этой теме будут рассмотрены два: char и string:
char: значения переменной – отдельный символ (один);
string: цепочка символов (несколько букв, символов, слов).
Например: var a:char; b:string;
Символьные переменные можно объединять (складывать):
f:='ab';
d:='cd';
s:=f+d; или s:='ab'+'cd';
результатом операции будет значение переменной s, равное 'abcd'.
В работе с символьными переменными могут использоваться операции отношения: =, <>, >, <, >=, <=, в которых проводится посимвольное сравнение кодов (номеров) символов. Если коды первых символов равны, то сравниваются коды следующих символов.
1. Наберите и отладьте программу imena (определение полного имени по короткому). После отладки проверьте ее при работе с именами Саша, Коля и Витя.
program imena;
uses crt;
var ik, ip: string;
begin
clrscr;
write('Введите имя ');
readln (ik);
ip:= 'Я такого не знаю';
if ik = 'Саша' then ip:= 'Александр';
if ik = 'Коля' then ip:= 'Николай';
if ik = 'Петя' then ip:= 'Петр';
writeln (ip);
end.
2. Написать программу нахождения максимальной из двух величин a и b, запрошенных с клавиатуры. Используется дополнительная переменная m, которой присваивается значение большего из чисел a и b.
program r1;
uses crt;
var a, b, m:real;
begin
writeln('Максимум двух чисел');
write('Введи первое число ');
readln(a);
write('Введи второе число ');
readln(b);
if a>=b then m:=a else m:= b;
clrscr;
writeln('a =',a,' b =',b);
writeln('max =',m);
end.
Задачи для самостоятельного решения
1. Составить программу, чтобы компьютер запросил имя пользователя и его год рождения, затем подсчитал возраст человека, в зависимости от возраста разработайте вариант диалога с пользователем (еще не учишься, учишься в таком-то классе (использовать формулу!), уже не учишься).
2. Написать программу вычисления у в зависимости от значения х
y = 1/x при х < 0 y = 2*x 2 при других х
3. Написать программу вычисления у в зависимости от значения х
y = 1/ x 2 при х > 0 y = x/6 при других х
4. Запросить с клавиатуры координаты точки (X, Y) и горизонтального отрезка прямой (Xn, Xk, Yn) и определить, лежит точка на отрезке прямой или нет. Сообщение об этом вывести на экран.
Подсказка. Если координата Y точки не равна координате Y прямой, то НЕ лежит, если координата Х точки не находится в пределах между Хn начала и Хk конца прямой, то точка НЕ лежит на прямой.
5. Написать программу вычисления подоходного налога по формулам:
а) при сумме менее 2500 рублей налог не взимается,
б) от 2500 до 10000 руб, берется 13% от суммы,
в) при сумме более 10000 руб берется 1300 рублей плюс 15% от суммы превышающей 10000 рублей.
Указание: программу проверить при суммах 1000, 8000 и 12000 руб. Ответы должны быть соответственно 0, 1040 и 1600 руб.
6. Запросить с клавиатуры 3 стороны треугольника и по ним определить, является ли он прямоугольным, сообщение вывести на экран.
Подсказка. Для каждой стороны применить теорему Пифагора и проверить, выполняется ли она. Если выполняется, то треугольник является прямоугольным. Переменные должны быть целыми числовыми. Функция квадрата - sqr(x), корня квадратного - sqrt(x). Программу проверить при сторонах 3, 4, 5 - прямоугольный, а 4, 5, 6 - не прямоугольный.
7. Запросить радиус круга R и сторона квадрата А. Определить, поместится ли круг в квадрате. Круг поместится в квадрате, если диаметр круга меньше или равен стороне квадрата.
8. Запросить радиус круга R и сторона квадрата А. Определить, поместится ли квадрат в круге. Квадрат поместится в круге, если диагональ квадрата меньше или равна диаметру окружности.
9. Написать программу для определения подходящего возраста для вступления в брак, используя следующее соображение: возраст девушки равен половине возраста мужчины плюс 7, возраст мужчины определяется соответственно как удвоенный возраст девушки минус 14. Данные для проверки работы программы задать самостоятельно.
10. Написать программу, контролирующую знание закона Ома. Обучаемый вводит формулу закона Ома в символьную переменную, которая далее сравнивается с правильным ответом, хранящимся в другой символьной переменной.
11. Написать программу вычисления значения функции у
у = x 2, если -2 <= x <= 2, у = 4 в остальных случаях.
12. Задать с помощью условного оператора следующие действия:
а) меньшее из двух значений переменных вещественного типа х и у заменить 0, а в случае их равенства заменить нулями оба;
б) наибольшее их трех различных значений переменных x, y, z уменьшить на 0.3
13. Найти сопротивление цепи из двух соединенных проводников. Сопротивления проводников и тип соединения запрашивать с клавиатуры. При последовательном соединении проводников R = R1 + R2, при параллелельном соединении проводников R = R1 * R2/(R1 + R2)
Упражнения
Выполните задания с If1 по If15 по электронному задачнику (стр.20). Открыть его можно в режиме Помощь – Электронный задачник РТ.
ТЕМА 4. Операторы цикла
Циклы применяются для повторения какой-либо последовательности операторов несколько раз. В Паскале существуют три вида циклов:
- Цикл For (со счетчиком);
- Цикл While (с предусловием);
- Цикл Repeat (с постусловием).
Оператор цикла For
Цикл for позволяет выполнить серию действий заданное число раз.
Общая форма цикла for такова:
for i:=start to limit do
тело цикла
или
for i:=start downto limit do
тело цикла
где start и limit – переменные программы
В данной конструкции «i» играет роль управляющей переменной цикла или счетчика и должна быть только целого типа.
Слово start – обозначает здесь начальное значение переменной a, limit – ее конечное значение. Тело цикла должно состоять из одного оператора, но можно поместить в тело цикла несколько операторов, для этого их нужно взять в логические скобки begin – end.
Цикл for выполняется следующим образом. Сначала производится инициализация (присваивание начального значения) i – его начальным значением становится start.
Если i меньше или равно limit, тело цикла выполняется (при значении i равном start). Всякий раз, когда тело цикла завершается, значение i автоматически увеличивается на 1, и тело цикла выполняется вновь, но уже с новым (следующим по порядку) значением i.
Циклические повторения тела будут продолжаться до тех пор, пока не будет превзойдено конечное значение. Когда это случится, цикл завершится, и будет выполняться строка программы, непосредственно следующая за конструкцией For.
Если в теле цикла находится несколько операторов, обрамленные парой слов-ограничителей begin и end, то общая форма цикла выглядит следующим образом:
for i:= start to limit do
begin
предложение 1;
предложение 2;
.............
предложение n
end;
В этой структуре при каждом входе в тело цикла будут выполняться предложение 1, предложение 2,..., предложение n.
В варианте цикла For со словом downto (вместо to) переменная пробегает последовательность значений от начального к конечному в обратном порядке, уменьшая каждый раз на 1. Внешне это выглядит так:
for i:= limit downto start do
тело цикла
1. Наберите следующую программу. Компьютер выведет на экран в столбик 15 случайных чисел от 8 до 39.
program sly;
uses crt;
var c, s: integer;
begin
writeln('15 случайных чисел от 8 до 40');
for c:=1 to 15 do
begin
s:= random(32) + 8; {Генерируется случайное число в диапазоне от 0 до 31, затем
к нему прибавляется 8, получаем случайное число от 8 до 39}
writeln (s);
end;
end.
Самостоятельно измените программу так, чтобы на экране были напечатаны в строчку 8 случайных дробных чисел от 5 до 25.
2. Напечатать таблицу стоимости порций сыра стоимостью 280 рублей от 100 г до 1 кг с шагом 100 г.
program sir;
uses crt;
var s,k:real;
c:integer;
begin
clrscr;
writeln('таблицa стоимости порций сыра');
for c:=1 to 10 do
begin
k:=280*c/10;
writeln (c*100,' г стоит ',k,' рублей');
end;
end.
Задачи для самостоятельного решения
1. Вычислить сумму первых 10 натуральных чисел. Использовать счетчик типа S=S+A, т.е. счетчик суммы. Использовать управляющую переменную цикла.
2. Напечатать таблицу соответствия между весом в фунтах и весом в кг для значений от 1 до 10 фунтов с шагом 1 фунт. 1 фунт=400 г.
3. Напечатать таблицу перевода расстояний в дюймах в сантиметры (1 дюйм=2.54 см) для значений от 1 до 10 дюймов с шагом 1.
4. Напечатать таблицу перевода температуры по Фаренгейту в градусы по Цельсию от 15 до 30. Перевод осуществляется по формуле F=1.8*C+32.
5. Запросить с клавиатуры в цикле 5 любых целых чисел, найти их сумму и среднее арифметическое, результаты вывести на экран.
6. Напечатать все нечетные натуральные числа от 1 до 50 в столбик. Использовать управляющую переменную цикла.
7. Напечатать все четные, натуральные числа в диапазоне, заданном пользователем с клавиатуры в строку. Использовать управляющую переменную цикла.
8. Составить таблицу умножения для числа 12 в виде:
12 * 2 = 24
12 * 2 = 24
12 * 3 = 36 и т.д. до
12 * 10 = 120
9. Вычислить сумму квадратов первых 7 натуральных чисел.
10. Вычислить все числа Фибоначчи от 3-го до N-го. Числа Фибоначчи образуют последовательность, у которой каждый очередной член равен сумме двух предыдущих:
0 → 1 → 1 → 2 → 3 → 5 → 8 → 13 → 21 → 34...
2+3=5 13+21=34
Упражнения
Выполните задания с For1 по For25 по электронному задачнику (стр.25). Открыть его можно в режиме Помощь – Электронный задачник РТ.
ТЕМА 5. Графика в Паскаль АВС
Основные графические процедуры
По умолчанию размеры графического экрана 640 на 400 точек.
Все графические объекты имеют определенный цвет. Каждому цвету соответствует название:
clBlack – черный
clPurple – фиолетовый
clWhite – белый
clMaroon – темно-красный
clRed – красный
clNavy – темно-синий
clGreen – зеленый
clBrown – коричневый
clBlue – синий
clSkyBlue – голубой
clYellow – желтый
clCream – кремовый
clAqua – бирюзовый
clOlive – оливковый
clFuchsia – сиреневый
clTeal – сине-зеленый
clGray – темно-серый
clLime – ярко-зеленый
clMoneyGreen – цвет зеленых денег
clLtGray – светло-серый
clDkGray – темно-серый
clMedGray – серый
clSilver – серебряный
Также можно задать цвет номером, например random(16777215) – случайный цвет из всей палитры цветов Паскаля
Ниже указаны некоторые процедуры модуля GraphАВС, применяющиеся для построения примитивов.
строкарезультат
setpixel(x,y,c) построить точку (x,y) цветом c
lineto(x,y) рисует отрезок от текущего положения пера до точки (x,y)
line(x1,y1,x2,y2) соединить две точки отрезком
rectangle(x1,y1,x2,y2) построить прямоугольник с заданными концами
диагонали и сторонами, параллельными осям
координат
circle(x,y,r) построить окружность с центром (x,y) и радиусом R
arc(x,y,a,b,r) построить дугу окружности: a,b – начальный
и конечный углы в градусах
ellipse(x1,y1,x2,y2) нарисовать эллипс, заданный описанным
прямоугольником с вершинами (x1,y1) и (x2,y2)
setpencolor(с) устанавливает текущий цвет рисунка
floodfill(x,y,c) заливает область цветом c, начиная с точки (x,y)
Пример программы
Начертить на экране 15 окружностей уменьшающегося радиуса, чтобы радиус был в 10 раз больше номера окружности.
program okr;
uses crt, graphabc;
var t:integer;
begin
for t:=15 downto 1 do
circle(300,220,t*10);
end.
Пример графической программы:
Простейшие задачи на графику:
1. В центре окна (640х400) нарисовать окружность радиусом 40 и закрасить ее красным цветом.
2. В центре окна (640х400) нарисовать прямоугольник 80х50 и закрасить его зеленым цветом.
3. По углам окна (640х400) нарисовать по одной окружности радиусом 15 и закрасить их разными цветами.
4. В центре окна (640х400) нарисовать квадрат 80х80, в его центре нарисовать окружность радиусом 40 и закрасить их разными цветами.
5. Нарисовать несложный домик и около него простую фигурку человечка.
6. Нарисовать в центре экрана простой самолетик на взлетной полосе и вдоль нее несколько деревьев.
Дополнительные задания: использование графики в цикле
1. Расставить на экране 100 точек со случайными координатами X и Y ("звездное небо"). Координаты выбирать с помощью random.
2. Нарисовать в центре экрана Олимпийские кольца.
3. Расставить на экране 30 окружностей со случайными координатами X и Y, случайного радиуса и цвета ("мыльные пузыри").
4. Через точку в центре экрана провести 20 отрезков, вторая координата которых выбирается случайно ("разбитое стекло").
5. Написать графическую иллюстрацию к задаче: запросить с клавиатуры координаты точки (X, Y) и горизонтального отрезка прямой (Xn, Xk, Yn) и определить, лежит ли точка на прямой. Сообщение вывести на экран.
ТЕМА 6. Виды циклов (продолжение).
Построение изображений в графическом режиме (продолжение)
Если число повторений заранее известно, то подходящей конструкций является оператор For. В противном случае следует использовать операторы While или Repeat.
Для управления циклом можно использовать Break и Continue. Break преждевременно завершает оператор цикла, Continue продолжает цикл со следующей итерации (следующего прохода) этого оператора, не завершив текущую.
Их использование считается нежелательным и должно применяться лишь в особых случаях.
Оператор цикла с постусловием (repeat)
Общая конструкция цикла:
repeat
тело цикла
until условие
Цикл repeat – until работает следующим образом. Сначала выполняется тело цикла. По достижению пункта until проверяется условие. Если оно не выполняется, тело цикла выполняется снова, завершаясь новой проверкой условия. Если же условие выполнено, то тело цикла больше не повторяется, цикл завершается, а программа переходит к выполнению предложения, следующего за until. В этом цикле не используются ограничители begin-end.
Условие может быть как числовым (например, until а=25), тогда счетчик (а:=a+1 или любой другой шаг) должен быть реализован внутри цикла, так и нечисловым (until keypressed).
Таким образом, после until ставится условие выхода из цикла. Последовательность операторов выполнится, по крайней мере, один раз, поскольку проверка условия производится после каждого выполнения последовательности операторов.
Пример использования оператора цикла с постусловием:
program sumnum;
var num, sum: integer;
begin
num:=0;
sum:=0;
repeat
num:=num+1;
sum:=sum+num;
writeln (num,' ',sum);
until num=5;
writeln (num,' ', sum)
end.
Оператор цикла с предусловием (while)
|
|
|
