Главная | Обратная связь | Поможем написать вашу работу!
МегаЛекции

Комбинированный тип данных. Запись. Описание записи. Доступ к полям записи. Оператор With. Примеры решения задач.




Довольно часто вполне оправданным является представление некоторых элементов в качестве составных частей другой, более крупной логической единицы. представляется естественным сгруппировать информацию о номере дома, названии улицы и городе в единое целое и назвать адресом, а объединенную информацию о дне, месяце и годе рождения - датой. В языке Паскаль для представления совокупности разнородных данных служит комбинированный тип запись.

Запись и массив схожи в том, что обе эти структуры составлены из ряда отдельных компонент. В то же время, если компоненты массива должны быть одного типа, записи могут содержать компоненты разных типов.

Приведем пример описания переменной, имеющей структуру записи:

Var
Address: Record
HouseNumber: Integer;
StreetName: String[20];
CityName: String[20];
PeopleName: String;
End;

Отметим, что поля StreetName и CityName имеют одинаковый тип: String[20]. Поскольку в описании эти поля могут располагаться в любом порядке, то можно сократить описание записи с полями одинакового типа. Сокращенное описание записи Address выглядит следующим образом:

Var
Address: Record
HouseNumber: Integer;
StreetName, CityName: String[20];
PeopleName: String;
End;

Каждая компонента записи называется полем. В переменной записи Address поле с именем HouseNumber само является переменной типа Integer, поле StreetName - двадцатисимвольной строкой и т.д.

Для того чтобы обратиться к некоторому полю записи, следует написать имя переменной и имя поля. Эти два идентификатора должны разделяться точкой.

Оператор, который присваивает полю HouseNumber значение 45, выглядит так:

Address.HouseNumber:= 45;

Таким же образом присваиваются значения другим полям записи Address:

Address.StreetName:= 'Профсоюзная';
Address.CityName:= 'Сургут';
Address.PeopleName:= 'Петрова Алла Ивановна';

Каждое поле записи Address можно рассматривать как обычную переменную, которую можно напечатать или использовать в расчетах. Вместе с тем запись может использоваться как единое целое. В этом случае надо ввести тип записи.

Предположим, имеется следующее описание:

Type
Date = Record
Day: 1..31;
Month: (Jan, Feb, Mar, Apr, May, Jun, Jul, Aug, Sep, Oct, Nov, Dec);
Year: Integer;
End;
Var
HisBirth, MyBirth: Date;

После приведенного описания переменные HisBirth и MyBirth имеют тип записи Date. Помимо действий над отдельными полями записей HisBirth и MyBirth можно выполнять операции над всей записью. Следующий оператор присваивания устанавливает равенство значений записей HisBirth и MyBirth:

HisBirth:= MyBirth;

Это присваивание эквивалентно следующей последовательности операторов:

HisBirth.Day:= MyBirth.Day;
HisBirth.Month:= MyBirth.Month;
HisBirth.Year:= MyBirth.Year;

Для переменных одного типа можно проверить выполнение отношения равенства или неравенства ("=", "<>"). После выполнения приведенных выше присваиваний следующее булево выражение будет иметь значение True:

HisBirth = MyBirth;

Рассмотрите пример описания процедуры, которая получает запись в качестве параметра-значения и печатает дату в сокращенной стандартной форме, используя формат (MM-DD-YYYY).

Procedure WriteDate(OneDate: Date);
Begin
Write(Ord(OneDate.Month)+1);
Write('-');
Write(OneDate.Day:2);
Write('-');
Write(OneDate.Year:4);
End;

Так как на тип компонент массива не накладывается ограничений, то можно использовать массив, компонентами которого являются записи. Посмотрите описание такого массива:

Var

Birthdays: Array [1..Persons] of Date;

Чтобы обратиться к некоторому полю определенной записи массива, следует определить имя массива, индекс интересующей записи и имя необходимого поля.

Например, следующий оператор печатает содержимое поля Year записи Birthdays[3]:

Write(Birthdays[3].Year);

Примечание. Поля записи в свою очередь тоже могут быть массивами, множествами, записями.

Задание. Рассмотрите следующие описания:

Type
Date = Record
Day: 1..31;
Month:1..12;
Year: 1..9999
End;
Reminder = Record
Message: Array [1..5] of String;
Event: Date
End;
Var
Today: Date;
Memos: Array [1..100] of Reminder;
Calendar: Array [1..365] of Date;

Запишите в тетрадь, какой тип, если он определен, у следующих идентификаторов?

а) Today.Year
б) Memos [2]
в) Memos [4].Month
г) Calendar [200]
д) Memos [16].Message[2]
е) Memos [16].Message[1],[2]
ж) Calendar[1].Date
з) Memos [10].Event

Задание. Составьте программу, организующую ввод наиболее полной информации о людях и вывод интересующей информации на экран.

Приведем описание массива, компоненты которого являются записями:

Var
Payroll: array [1..Workers] of
record
FirstName, LastName: string;
Residence: record
HouseNumber: real;
StreetName, CityName: string;
StateName: Array [1..2] char;
ZipCode: integer;
end;
Phone: record
AreaCode, Exchenge: 1..999;
Line: 1..9999;
rnd;
PayScale: 'A'..'G';
end;

Отметим, что два поля Residence и Phone являются записями. Как выполнить обращение к полям этих записей? Как распечатать условный шифр рабочего № 7? Поскольку это поле располагается во вложенной записи, то следует указать как имя самой записи, так и имя записи, в которую данная запись входит.

write (Payroll[7].Residence.ZipCode);

Аналогично приведенное присваивание корректирует шифр рабочего № 23:

Payroll[23].Phone.AreaCode:=804;

Оператор if, представленный ниже, выполняет проверку инициала рабочего № 58:

if Payroll[58].LastName[1] in ['T'..'Z'] Then...

Соблюдение всех правил перечисления индексов и имен полей при составлении ссылок является довольно утомительным занятием, часто приводящим к ошибкам. В некоторых программах, содержащих большое количество обращений к одному и тому же полю, такое положение приводит к однообразному повторению. Чтобы облегчить выполнение многократных ссылок для описанных структур вводится оператор With (в переводе с английского - предлог "с").

Общая форма записи:

with <имя переменной> do <оператор>

В рамках оператора, определяемого внутри оператора With, к полям определяемой переменной можно обращаться просто по имени. Например,

with Payroll[7].Residence do
ZipCode:= 2345;
for i:= 1 to Workers do
with Payroll[i] do
if PayScale < 'G'
then
PayScale:= Succ(PayScale);

Оператор with позволяет более компактно представлять часто используемые переменные. Посмотрите это на примере фрагмента программы, печатающего адрес рабочего № 14:

with Payroll[14].Residence do
begin
writeln(HouseNumber,' ',StreetName);
writeln(CityName,',',StateName,',',ZipCode);
end;

В рамках составного оператора, следующего за with, каждое обращение к имени поля автоматически связывается с записью Payroll[14].Residence. Печать адресов всех рабочих выполняется при помощи следующего оператора цикла:

for i:= 1 to Workers do
with Payroll[i].Residence do
begin
writeln(HouseNumber,' ',StreetName);
writeln(CityName,',',StateName,',',ZipCode);
end;

Операторы with могут быть вложенными. Приведенные ниже три оператора эквивалентны друг другу:

  1. Payroll[i].Residence.HouseNumber:= 50;
  2. with Payroll[i].Residence do
    HouseNumber:= 50;
  3. with Payroll[i] do
    with Residence do
    HouseNumber:= 50;

Однако недопустимым является использование вложенных операторов With, в которых указываются поля одного типа, поскольку возникает неоднозначность конструкции. По этой причине приведенное использование вложенных операторов With является неверным:

with Payroll[5] do
with Payroll[17]do
PayScale:='A';

Следует очень внимательно подходить к использованию вложенных операторов With, применение которых не только может привести к ошибкам, но также к потере наглядности структуры программы. Хотя оператор With является стандартным средством сокращения, его полезность должна еще проявиться. Конечной целью всякого хорошего программиста является написание не только короткой, но и понятной программы.

Рассмотрите решение задачи.

Задача. В массиве хранятся данные об учениках класса: школа, фамилия, класс. Вывести список учеников, которые учатся в восьмом классе.

Program LipovsevM;
Uses
Crt;
Type
Uchenik=record
Shkola: integer;
Fam: string[15];
Klass: integer;
end;
Var
I,n,a,j: integer;
Massiv: array[1..100] of Uchenik;
Рrocedure Poisk;
Begin
for i:=1 to n do
if massiv[i].klass=8
then
with massiv[i] do
writeln(Shkola:4,' ',Fam:15,' ',klass);
End;
Begin
ClrScr;
writeln('Введите число учеников ');
write('->');
read(n);
for i:=1 to n do
begin
writeln('Введите через пробел номер школы и фамилию ученика ');
write('->');
with massiv[i] do
begin
readln(Shkola,Fam);
write('Введите класс ученика (только число) ->');
read(Klass);
end;
end;
writeln('Ученики 8-ых классов:');
writeln('Школа Фамилия Класс');
writeln('---------------------------------');
Poisk;
ReadKey;
End.

 

Записи, рассмотренные выше - это записи с фиксированными частями. Они имеют в различных ситуациях строго определенную структуру. Соответственно записи с вариантами в различных ситуациях могут иметь различную структуру.

Предположим, что написана программа для введения списка библиографических ссылок. Если известно, что все входы в этом списке - ссылки на книги, то можно использовать следующее описание:

Const
Kol = 1000;
Type
Entry = Record
Autor, Title, Publisher, City: String;
Year: 1..2000;
End;
Var
List: Array[1..Kol] of Entry;

Что произойдет, если некоторые из входов не являются ссылками на книги, а содержат ссылки на журнальные статьи. Если ограничиваться только записями с фиксированными частями, то следует описать различные массивы для каждого вида записей. Использование записей с вариантами позволяет образовать структуру, каждый вход которой соответствует содержанию записи. Опишем новый тип, в котором перечислены различные входы:

Type
EntryType = (Book, Magazine);

Теперь можно привести скорректированное описание Entry

Type
Entry = Record
Autor, Title: String;
Year: 1..2000;
Case EntryType of
Book: (Publisher, City: String);
Magazine: (MagName: String,
Volume, Issue: Integer)
End;

Это описание делится на две части: фиксированную и вариантную. Поля Autor, Title, Year составляют фиксированную часть. Оставшаяся часть описания Entry образует вариантную часть, структура которой, подобно хамелеону, может меняться в пределах двух альтернативных определений.

Первая строка вариантной части представляет оператор Case, который отличается тем, что в качестве селектора применяется идентификатор типа. Значения EntryType используются в качестве имен двух альтернатив определения записи. Когда эта компонента имеет значение Book, можно обращаться к следующим полям:

Autor, Title, Year, Publisher, City

С другой стороны, когда она принимает значение Magazine, то можно обращаться к таким полям:

Autor, Title, Year, MagName, Volume, Issue

В такой ситуации возникает естественный вопрос: как программа может хранить информацию о текущем состоянии каждой записи? Другими словами, каким образом можно узнать, что List[3] содержит ссылку на книгу, а List[4] - ссылку на журнал?

Естественное решение этой проблемы заключается в добавлении в каждой записи нового поля, называемого полем тега. Язык Паскаль позволяет за счет совмещения задать описание поля тега в сокращенной форме:

Type
Entry = Record
Autor, Title: String;
Year: 1..2000;
Case TAG: EntryType of
Book: (Publisher, City: String);
Magazine: (MagName: String,
Volume, Issue: Integer)
End;

Поле, названное TAG, является переменной типа EntryType. Когда запись содержит ссылку на книгу, TAG следует присвоить значение Book. Когда запись содержит ссылку на журнал, TAG следует присвоить значение Magazine.

Рассмотрите последовательность операторов, где в RefList[12] помещается ссылка на книгу:

RefList[12].TAG:= Book;
RefList[12].Autor:= 'Thomas Hobbes';
RefList[12].Title:= 'Leviathan';
RefList[12].Year:= 1651;
RefList[12].Publisher:= 'Andrew Crooke';
RefList[12].City:= 'London';

Для определения состояния записи с вариантами достаточно проверить значение поля тега. Рассмотрите процедуру, выводящую на экран переданную ей запись.

Procedure PrintRef(Citation: Entry);
Begin
Writeln(Citation.Autor);
Writeln(Citation.Title);
Writeln(Citation.Year);
If Citation.TAG = Book
Then
Writeln(Citation.Publisher,', ',Citation.City)
Else
Begin
Writeln(Citation.MagName);
Writeln(Citation.Volume'-',Citation.Issue)
End;
End;

Вариантная часть может содержать произвольное число альтернатив. Хотя перечисляемые типы предпочтительнее, так как они более понятны, тем не менее для именования альтернатив записи с вариантами могут использоваться идентификаторы произвольного порядкового типа.

Очевидно, что один и тот же идентификатор поля не может дважды использоваться при описании записи, даже если он применяется в определении различных альтернатив записи с вариантами. Если же это условие не выполняется, то обращение к такому идентификатору приведет к непредсказуемому результату.

Наверное Вы уже обратили внимание, что описание записи с вариантами может иметь единственный закрывающий оператор End. Поскольку любая запись может иметь лишь одну вариантную часть, то End, который является индикатором конца описания записи, служит для обозначения конца и ее вариантной части.

Задание. Опишите под именем Figure вариантную запись. Если переменная типа Figure представляет собой круг, то она должна содержать радиус соответствующей окружности. Если эта переменная представляет прямоугольник, то она должна содержать величину угла и длины двух сторон, образующих этот угол и т. д. Выполните одну из следующих задач:

а) Напишите процедуру, которая запрашивает и получает значение типа Figure от пользователя.

б) Напишите функцию, которая получает на входе значение типа Figure и вычисляет площадь фигуры.

в) Напишите функцию, которая получает на входе значение типа Figure и вычисляет периметр фигуры.

г) Напишите булеву функцию, которая получает на входе два значения типа Figure и определяет, помещается ли первая фигура внутри второй.

Рассмотрите два примера решения задачи с вариантами.

Задача. В массиве хранятся данные об учениках класса: фамилия, имя, отчество, адрес (улица, дом, квартира) и домашний телефон (если есть). Вывести список учеников, до которых нельзя дозвониться.

Program LipovsevM;
Uses
Crt;
Type
Uchenik=record
Name:string[10];
Fam:string[15];
Otch:string[15];
Ulica:string[20];
Dom:string[5];
Kvartira: integer;
case tel: boolean of
False:();
True:(Telefon:string[15]);
end;
Var
Massiv: array[1..100] of Uchenik;
I,n: integer;
Otvet: 0..1;
Begin
ClrScr;
TextColor(9);
write('Введите число учеников->');
readln(n);
for i:=1 to n do
begin
with massiv[i] do
begin
write('Введите имя ',i,'-го ученика ->');
readln(name);
write(''Введите фамилию ',i,'-го ученика ->');
readln(fam);
write(''Введите отчество ',i,'-го ученика ->');
readln(otch);
write(''Введите улицу ',i,'-го ученика ->');
readln(ulica);
write(''Введите дом ',i,'-го ученика ->');
readln(dom);
write(''Введите квартиру ',i,'-го ученика ->');
readln(kvartira);
write('Есть ли у ',i,'-го ученика телефон (0-нет, 1-да->');
readln(otvet);
if otvet=1
then
begin
tel:=True;
write(''Введите телефон ',i,'-го ученика ->');
readln(telefon);
end;
end;
End;
TextColor(red);
writeln('Список учеников, до которых нельзя дозвониться:');
for i:=1 to n do
begin
with massiv[i] do
if tel=False
then
begin
writeln('Имя:',name);
writeln('Фамилия:',fam);
writeln('Отчество:',otch);
writeln('Улица:',ulica);
writeln('Дом:',dom);
writeln('Квартира:',kvartira);
end;
end;
ReadKey;
End.

Задание. Будьте готовы объяснить решение предыдущей задачи и последующей учителю. Если затрудняетесь в чтении алгоритма решения задачи, то обратитесь за помощью к учителю.

Задача. Осуществить ввод общей информации (автор, название) о содержимом библиотеки: имеющиеся книги, журналы, газеты. Если книга, то осуществить дополнительно ввод года издания; если журнал - год издания и номер журнала; если газета - год, месяц и день выхода газеты. Осуществить вывод информации, поиск литературы по типу издания.

Program SedihA;
Uses
Crt;
Type
TypePubl = (Book,Journal,Newspaper);
Litter = record
Title: string[50];
Author: string[50];
case V: TypePubl of
Вook: (YearB: integer);
Journal: (Num: 1..12;
YearJ: 1900..2000);
Newspaper: (Day: 1..31;
Month: 1..12;
YearN: integer);
end;
Const
Count = 10;
Var
Katalog: array [1..count] of Litter;
NumArray: 1..count;
YesLitter: Boolean;
Vybor: byte;
Edition: Type_Publ;
CountFind: integer;
Procedure InputData;
Begin
writeln;
writeln('Введите данные о литературе ', NumArray,':');
write('Введите число, указывающее вид издания: ');
Write('1-книга, 2-журнал, 3-газета: ');
readln(Vybor);
case Vybor of
1: Katalog[NumArray].v:=Book;
2: Katalog[NumArray].v:=Journal;
3: Katalog[NumArray].v:=Newspaper;
end;
with katalog[NumArray] do
begin
write('Фамилия автора? ');
readln(Author);
write('Название? ');
readln(Title);
case v of
Book: begin
write('Год издания? ');
readln(YearB);
end;
Journal: begin
write('Номер? ');
readln(Num);
write('Год издания? ');
readln(YearJ);
end;
Newspaper: begin
write('Дата издания: День? ');
readln(Day);
write('Месяц? ');
readln(Мonth);
write('Год? ');
readln(YearN);
end;
end;
end;
End;
Procedure WriteData;
Begin
writeln;
with Katalog[NumArray] do
begin
writeln('Название: ',Тitle);
writeln('Фамилия автора: ',Аuthor);
case v of
Book: writeln('Год издания: ',YearB);
Journal: begin
writeln('Номер: ', Num);
writeln('Год издания: ',YearJ);
end;
Newspaper: writeln('Дата издания: День: ',Day,' Месяц: ',Month,'Год: ',YearN);
end;
end;
Еnd;
Procedure FindLitter;
Begin
writeln('Поиск литературы по типу издания: ');
writeln;
write('1-книга, 2-журнал, 3-газета: ');
readln(Vybor);
case Vybor of
1: Edition:=Book;
2: Edition:=Journal;
3: Edition:=Newspaper;
end;
YesLitter:=False;
CountFind:=0;
for num_array:=1 to count do
if katalog[num_array].v = edition
then
begin
YesLitter:=True;
CountFind:=CountFind+1;
WriteData;
end;
if not YesLitter
then
writeln('В иблиотеке нет такой литературы')
else
writeln('Всего в библиотеке ',CountFind,' таких изданий');
End;
Begin
ClrScr;
for NumArray:=1 to Count do
InputData;
writeln;
FindLitter;
End.

Выберите с учителем задачи для решения из предложенного списка. Задачи решайте с помощью записей с вариантами. Для проверки учителем решения Вашей задачи приготовьте не только листинг и файл с протестированной задачей, но и 3-4 теста для демонстрации различных вариантов введения информации и вывода на экран.

  1. Составьте список группы спортсменов, участвовавших в соревнованиях по спортивной гимнастике, включающей N человек. Для каждого гимнаста указажите фамилию, имя, название общеобразовательной школы, класс, результаты по следующим видам:
    • брусья,
    • вольные упражнения,
    • прыжки на дорожке,
    • прыжки через коня;
    • для юношей
    • кольца,
    • перекладина,
    • для девушек
    • бревно


Составьте программу, которая обеспечивает ввод полученной информации, распечатку ее в виде таблицы, а также распечатайте анкетные данные спортсменов,

а) показавших лучший результат по каждому виду;
б) показавших лучший результат по всем видам многоборья,
в) не получивших ни одного призового места.

  1. Составьте прайс-лист магазина "Техника", включающий в себя марку предприятия-производителя, страну-производитель и,в зависимости от этих данных, наименования товара, его цену, количество единиц товара на складе. Составьте программу, которая обеспечивает ввод полученной информации, распечатку ее в виде таблицы. Выведите на экран меню, а затем информацию о товаре в зависимости от запроса покупателя.
  2. Составьте прайс-лист аптеки "Эксон", включающий в себя наименования товара, страну-производитель, его цену, его состав, рекомендации врача в зависимости от возраста больного (дозировка, наличие сопутствующих расстройств). Информацию о каждом виде товара оформите в программе в виде записи с вариантами. Совокупность записей объедините в массив. Составьте программу, которая обеспечивает ввод полученной информации, распечатку ее в виде таблицы. Выведите на экран меню, а затем информацию о товаре в зависимости от запроса покупателя.
  3. Составьте банк данных членов своей семьи и (или) ближайших родственников, включающий в себя имя, отчество, степень родства, и в зависимости от введенной информации в поле <МолодойСтарый> придумайте варианты полей (например, хобби, любимый анекдот, количество медалей, количество внуков, любимый напиток, любимая девочка, лучший друг, объем имеющегося наследства). Информацию о каждом родственнике оформите в программе в виде записи с вариантами. Совокупность записей объедините в массив. Составьте программу, которая обеспечивает ввод полученной информации, распечатку ее в виде таблицы. Выведите на экран меню, а затем информацию о родне в зависимости от Вашего запроса.
  4. Составьте банк данных своих одноклассников, включающий в себя фамилию, имя, почтовой и (или) электронный адрес, телефон, а также в зависимости от поля <Друг> наличие соответствующей дополнительной информации по своему усмотрению. Информацию о каждом товарище оформите в программе в виде записи с вариантами. Совокупность записей объедините в массив. Составьте программу, которая обеспечивает ввод полученной информации, распечатку ее в виде таблицы. Выведите на экран меню, а затем информацию о друзьях в зависимости от Вашего запроса.
  5. Составьте банк данных кинологов, включающий в себя фамилию и имя владельца собаки, кличку собаки, породу собаки, день и год рождения собаки, а также в зависимости от породы наличие соответствующей дополнительной информации по своему усмотрению. Информацию о каждом владельце оформите в программе в виде записи с вариантами. Совокупность записей объедините в массив. Составьте программу, которая обеспечивает ввод полученной информации, распечатку ее в виде таблицы. Выведите на экран меню, а затем информацию в зависимости от Вашего запроса.
  6. Составьте банк данных районного отдела милиции, включающий в себя фамилию, имя и отчество нарушителя, дату рождения, и в зависимости от поля <Судимость> наличие соответствующей дополнительной информации по своему усмотрению (например, наличие клички, мера наказания, срок заключения). Информацию о каждом нарушителе оформите в программе в виде записи с вариантами. Совокупность записей объедините в массив. Составьте программу, которая обеспечивает ввод полученной информации, распечатку ее в виде таблицы. Выведите на экран меню, а затем информацию в зависимости от Вашего запроса.
  7. Составить программу, которая бы считывала и анализировала введенную информацию о пользователях городской телефонной сети. Запись должна иметь поля:
    • фамилию, имя, отчество;
    • номер телефона;
    • адрес;
    • наличие задолженности по оплате (в массиве по всем месяцам года).


Предусмотрите в программе варианты полей в зависимости от заполнения поля <Задолженность по оплате> (например, размер долга, отключение от междугородней сети, подсчет пени и другое). По введенной информации и запросу пользователя предусмотреть в программе вывод предупреждения абонентов, имеющих задолженность, и какое-либо поощрение ответственным плательщикам.

  1. Составить программу, собирающую данные об авиакомпаниях и выдающую справку туристу до запрашиваемого места. Справка должна содержать:
    • название авиакомпании;
    • название рейса;
    • номер рейса;
    • тип самолета;
    • даты вылета (содержатся в массиве);
    • наличие мест в 1 и 2 классах.


Предусмотрите в программе варианты полей сервиса в зависимости от выбора поля <Класс>. В случае покупки билета, массив записей должен быть соответственно измениться.

  1. Познакомившись с содержанием предыдущих задач придумайте свою интересную задачу и решите ее.

Сортировка записей.

Рассмотрите решение задачи, наберите ее на компьютере, протестируйте, найдите в программе недостатки и устраните их. Дополните задачу комментариями и покажите учителю для оценки.

Задача 1. Во время лыжных соревнований в центральный судейский компьютер поступают данные в следующем виде: номер участника, его фамилия, страна и показанный результат. Составить программу, которая после ввода очередной информации выдает таблицу результатов участников в порядке ухудшения.

Program Ski;
Uses
Crt;
Type
inf= record
num: byte;
name,strana: string[30];
rez: real;
end;
Var
m: array [1..100] of inf;
i,j,k,l: integer;
Procedure Input;
Begin
write('Введите количество участников соревнований: ');
readln(k);
for i:=1 to k do
with m[i] do
begin
write('Введите номер участника: ');
readln(num);
write('Введите фамилию: ');
readln(name);
write('Какую страну представляет: ');
readln(strana);
write('Показанный результат: ');
readln(rez);
writeln;
end;
End;
Procedure Vich;
Var
o: real;
n,s:string;
nm: byte;
Begin
ClrScr;
for i:=1 to k-1 do
for j:=i+1 to k do
begin
if m[j].rez<m[i].rez
then
begin
o:=m[j].rez;{Меняем результаты}
m[j].rez:=m[i].rez;
m[i].rez:=o;
nm:=m[j].num;{Меняем номера}
m[j].num:=m[i].num;
m[i].num:=nm;
n:=m[j].name;{Меняем фамилии}
m[j].name:=m[i].name;
m[i].name:=n;
s:=m[j].strana; {Меняем страны}
m[j].strana:=m[i].strana;
m[i].strana:=s;
end;
end;
End;
Procedure Output;
Begin
for i:=1 to k do
with m[i] do
begin
writeln('',i,'-ое место занял:');
writeln('участник под номером: ',num);
writeln('Его фамилия: ',name);
writeln('Представляет страну: ',strana);
writeln('Показанный результат: ',rez:3:1);
writeln;
end;
End;
Begin
ClrScr;
Input;
Vich;
Output;
ReadKey;
End.

Задание. Дополните решенную Вами предыдущую задачу сортировкой по выбранному Вами полю записи и выводом отсортированного массива записей на экран. Сортировку осуществляйте с помощью одного из способов, выбранного учителем из предложенных:

  • сортировка вставкой;
  • сортировка выбором;
  • сортировка методом простого обмена;
  • сортировка с помощью рекурсии.

Задание. Выберите с учителем задачи для решения из предложенного списка. Для проверки учителем решения Вашей задачи приготовьте не только листинг и файл с протестированной задачей, но и 3-4 теста для демонстрации различных вариантов введения информации и вывода на экран.

  1. Среди N абитуриентов, сдававших экзамены по информатике, математике и английскому языку, выбрать всех отличников и всех учащихся, набравших в сумме не меньше проходного балла. Данные о проходном балле вводятся с клавиатуры.
  2. Среди N абитуриентов, сдававших экзамены по информатике, математике и английскому языку в перечисленном порядке, выбрать учащихся, не допущенных к сдаче следующего экзамена в связи с получением неудовлетворительной оценки по предыдущему экзамену. Выдать на экран список абитуриентов, удачно сдавших все экзамены.
  3. Составить программу, выдающую справку о номере квартиры, в которой проживает жилец. В доме имеется N квартир и проживает M человек. Пользователь вводит фамилию жильца. Если в доме поживает несколько жильцов с такой фамилией, то выдается сообщение о необходимости ввести инициалы. Если инициалы у нескольких жильцов совпадают, то необходимо ввести год рождения. Если с такими данными найдется один жилец (несколько), то вывести номер (номера) квартир, где он (они) проживают и все введенные о нем (них) сведения. Если жильца с такой фамилией нет, то вывести сообщение об этом.
  4. Составить программу, которая анализировала бы введенную информацию о пользователях городской телефонной сети и выдавала бы список абонентов, имеющих задолженность за месяц, а также считала пеню (вводится пользователем). Запись должна иметь поля:
    • месяц анализа данных;
    • фамилию, имя, отчество;
    • номер телефона;
    • адрес;
    • имеющиеся льготы по оплате;
    • абонентская плата;
    • стоимость междугородних разговоров;
    • стоимость дополнительных платных услуг.


По введенной информации и запросу пользователя предусмотреть в программе вывод предупреждения абонентов, имеющих задолженность.

  1. Составить программу, собирающую данные об авиакомпаниях и выдающую справку туристу до запрашиваемого места. Справка должна содержать:
    • название авиакомпании;
    • название рейса;
    • номер рейса;
    • тип самолета;
    • даты вылета (содержатся в массиве);
    • наличие мест в 1 и 2 классах;
    • стоимость перелета.


В случае покупки билета, массив записей должен быть соответственно измениться.

  1. Во время лыжных соревнований в центральный судейский компьютер поступают данные в следующем виде: номер участника, его фамилия, страна и показанный результат. Составить алгоритм, который после ввода очередной информации выдает таблицу результатов участников в порядке ухудшения.
  2. В экзаменационной ведомости фиксируются фамилии учеников, номера билетов, оценки, записанной прописью. Составьте подобную ведомость для группы из N человек на основе сформированного массива записей. Строка списка имеет следующий вид:

Иванов Александр билет № 12 (отлично)

Вывести информацию о результатах экзамена в следующем виде:

Количество экзаменуемых - 25
Сдали на "отлично" - 7
Сдали на "хорошо" - 10
Сдали на "удовлетворительно" - 7
Сдали на "неудовлетворительно" - 1
Не явились - нет

  1. По окончании школы ученики сдавали экзамены по литературе, математике, физике и информатике. Определите экзамен, на котором ученики получили наиболее высокий средний бал и выведите список учащихся в порядке убывания результатов по этому экзамену.
  2. Составить программу, организующую заполнение массива записями, содержащими информацию о здоровье детей в лагере отдыха. Запись должна содержать поля:
    • фамилия, имя ребенка;
    • дата прибытия в лагерь;
    • вес ребенка (на день прибытия, через 10 дней, через 20 дней);
    • рост ребенка;
    • возраст;
    • номер отряда;
    • наличие хронических заболеваний.


Вывести данные о детях, увеличивающих свой вес и о детях, которые худеют.

  1. Познакомившись с содержанием предыдущих задач придумайте свою интересную задачу и решите ее.
  Понятие подпрограммы. Процедуры и функции. Стандартные подпрограммы. Примеры употребления подпрограмм в решении задач.  
   

Определение. Подпрограмма - это отдельная функционально независимая часть программы. Любая подпрограмма обладает той же структурой, которой обладает и вся программа.

Подпрограммы решают три важные задачи:

  • избавляют от необходимости многократно повторять в тексте программы аналогичные фрагменты;
  • улучшают структуру программы, облегчая ее понимание;
  • повышают устойчивость к ошибкам программирования и непредвидимым последствиям при модификациях программы.

Очень важно понимать, что в подпрограммы выделяется любой законченный фрагмент программы. В качестве ориентиров просмотрите следующие рекомендации:

  1. Когда Вы несколько раз перепишите в программе одни и те же последовательности команд, необходимость введения подпрограммы приобретает характер острой внутренней потребности.
  2. Иногда слишком много мелочей закрывают главное. Полезно убрать в подпрограмму подробности, заслоняющие смысл основной программы.
  3. Полезно разбить длинную программу на составные части - просто как книгу разбивают на главы. При этом основная программа становится похожей на оглавление.
  4. Бывают сложные частные алгоритмы. Полезно отладить их отдельно в небольших тестирующих программах. Включение программ с отлаженными алгоритмами в основную программу будет легким, если они оформлены как подпрограммы.
  5. Все, что Вы сделали хорошо в одной программе, Вам захочется перенести в новые. Для повторного использования таких частей лучше сразу выделять в программе полезные алгоритмы в отдельные подпрограммы.

Подпрограммы могут быть стандартными, т.е. определенными системой, и собственными, т.е. определенными программистом.

Стандартная подпрограмма (процедура или функция) - подпрограмма, включенная в библиотеку программ ЭВМ, доступ к которой обеспечивается средствами языка программирования. Вызывается она по имени с заданием фактических параметров с типом описанным при описании данной процедуры в библиотечке процедур и функций.

Из набора стандартных процедур и функций по обработке одного типа информации составляются модули. Каждый модуль имеет своё имя (мы уже хорошо знакомы с модулями Crt, Graph). Доступ к процедурам и функциям модуля осуществляется при подключении этого модуля (Uses Crt, Graph).

Help содержит подробные описания предусмотренных средой программирования процедур и функций. Для вызова помощи при работе со стандартнымипроцедурами и функциями нужно поставить на имя подпрограммы курсор и нажать клавиши <Ctrl+F1>. Описание процедур и функций в Help строится по стандартному принципу.

Задание. Вызовите помощь по функции Cos и рассмотрите предоставленную информацию.

Сначала идет краткое описание подпрограммы (в одну фразу). Далее под словом Declaration (Объявление) следует интерфейсная часть процедуры или функции, которая особенно часто необходима для определения типа переменных при обращении к ним. Далее под словом Target приводятся платформы, на которых может использоваться подпрограмма: Windows, real (реальный режим DOS), protected (защищенный режим DOS). После слова Remarks следуют заметки, содержащие необходимые детали использования. В разделе See Also приведены имена подпрограмм, связанных с данной по смыслу или по совместному применению. Если перемещать курсор по этим именам (они выделяются курсорной рамкой), то выбрав одно из них (нажать клавишу <Enter>), можно получить справку по следующей функции. Каждая процедура и функция сопровождается примером применения, переключение к которому дает последняя строка программы. Любой текст из Help может быть скопирован в редактируемый файл обычными приемами копирования через буфер. Копирование примеров или заголовков функций облегчает работу.

Существует другой способ получения помощи по процедурам и функциям. Для этого нужно использовать пункт меню Help/Reserved words (зарезервированные слова) или Help/Standard units (стандартные модули).

Задание. Рассмотрите список процедур и функций, выберите какие-либо и просмотрите предлагаемую информацию.

В стандартных модулях содержится большое количество стандартных подпрограмм, но невозможно создать модуля, который бы содержал все нужные программисту подпрограммы. Поэтому большую роль в создании программ играют собственные подпрограммы, которые создает программист для решения конкретной задачи.

Существует два способа объединения программ и подпрограмм:

  1. Текст подпрограмм может быть приведен в разделе описания использующей их программы.
  2. Подпрограммы группируются в отдельных файлах, имеющих специальную структуру - модулях. Для того чтобы основная программа могла использовать модуль, он должен быть подключен к основной программе.

Первый способ применяется тогда, когда программа в целом не очень большая, а ее подпрограммы, скорее всего, не будут использоваться в других программах. Второй способ желателен, в частности, для той программы, которую Вы будете создавать в качестве курсовой работы при завершении учебы в городской школе юного программиста.

Структура текста подпрограммы соответствует структуре текста основной программы за двумя исключениями:

  • подпрограмма начинается с заголовка, содержащего имя подпрограммы, передаваемые в нее и возвращаемые от нее периметры, запись заголовка подпрограммы отличается от заголовка программы;
  • подпрограмма кончается не точкой, а точкой с запятой.

Вызов подпрограммы происходит при каждом употреблении ее имени в основной (или вызывающей) программе. При вызове подпрограммы выполнение основной программы приостанавливается, и управление передается в подпрограмму, где выполняются команды, заданные в ней. Подпрограмма завершается, если выполнены все ее процедуры до завершающего слова End или по специальной команде выхода из подпрограммы Exit. По окончании работы подпрограммы управление возвращается основной программе, иначе говоря, к первой команде, следующей за обращением к этой подпрограмме.

В языке Pascal определяются два типа подпрограмм - процедуры и функции. Основное различие между процедурой и функцией состоит в том, что процедура только выполняет какую-либо законченную последовательность действий, не возвращая результата работы в основную программу, а функция и выполняет действия, и возвращает результат.

Например, вызов функции

M:= MIN (X, Y)

вернет в основную программу значение наименьшего из двух чисел и это значение будет присвоено переменной M.

Любая подпрограмма должна быть описана до того, как она будет вызвана в программе или в другой подпрограмме. Все переменные, которые использует подпрограмма, могут быть либо глобальные либо локальные.

Определение. Глобальными называются переменные, объявленные в основной программе и доступные как программе, так и всем ее подпрограммам.

Определение. Локальными называются переменные, объявленные внутри подпрограммы и доступные только ей самой.

Обмен информацией между основной программой и подпрограммой может осуществляться только с помощью глобальных переменных.

Подпрограмма может использовать любые глобальные переменные кроме тех, которые имеют те же имена, что и локальные переменные. Переменные с совпадающими именами, которые могут быть описаны в основной программе или других подпрограммах, не имеют ничего общего с локальными переменными. если переменная описана. Если переменная описана в основной программе и не переопределена в подпрограмме, она может использоваться в подпрограмме. Память для локальных (т.е. описанных в подпрограмме) переменных выделяется на время исполнения данной подпрограммы в специальной области, называемой стеком. При завершении работы подпрограммы память освобождается, поэтому все внутренние результаты работы подпрограммы не сохраняются от одного обращен

Поделиться:





Воспользуйтесь поиском по сайту:



©2015 - 2024 megalektsii.ru Все авторские права принадлежат авторам лекционных материалов. Обратная связь с нами...